Function isValidRange(rngString As String) As Boolean
    'Function to check whether the provided string is a valid range
    Dim rng As Range
    On Error Resume Next
    Set rng = ActiveWorkbook.ActiveSheet.Range(rngString)
    If Err.Number <> 0 Then
        Exit Function
    End If
    isValidRange = True
End Function

Private Sub applyBtn_Click()
    Dim selectionRange As Range
    Dim cell As Range
    Dim oldFormula As String
    Dim newFormula As String
    Dim roundingFormat As Variant
    
    
    SaveSetting "MagnimetricsTools", "ApplyRounding", "roundingFormat", roundingTextBox.Value
    
    roundingFormat = roundingTextBox.Value
    If IsNumeric(roundingFormat) Then
        If roundingFormat <> Int(roundingFormat) Then
            roundingFormat = Round(roundingFormat, 0)
        End If
    Else
        roundingFormat = 0
        roundingTextBox.Value = 0
    End If
    
    If Not isValidRange(selectionRangeRef.Value) Then
        selectionRangeRef.Value = ""
        selectionRangeRef.SetFocus
        MsgBox "Error", vbCritical, "Selection Error"
        Exit Sub
    End If
    
    Set selectionRange = ActiveSheet.Range(selectionRangeRef.Value)
    
    For Each cell In selectionRange
        
        If cell.HasFormula Then
        
            oldFormula = cell.Formula
            
            'check if formula already has rounding
            If Left(cell.Formula, 6) <> "=ROUND" Then
                'wrap formula with round
                newFormula = "=ROUND(" & Right(oldFormula, Len(oldFormula) - 1) & "," & roundingFormat & ")"
                'MsgBox newFormula
                cell.Formula = newFormula
                
            Else
                'do nothing, it's already ROUNDed
            End If
        
        ElseIf IsNumeric(cell) Then
            'wrap number with round
                newFormula = "=ROUND(" & cell.Value & "," & roundingFormat & ")"
                'MsgBox newFormula
                cell.Formula = newFormula
        End If
    
    Next cell
    
    Unload Me
End Sub

Private Sub cancelBtn_Click()
    Unload Me
End Sub

Private Sub previewTextBox_Change()
    
    Dim roundingFormat As Double
    Dim previewNum As Double

    roundingFormat = roundingTextBox.Value
    If IsNumeric(roundingFormat) Then
        If roundingFormat <> Int(roundingFormat) Then
            roundingFormat = Round(roundingFormat, 0)
        End If
    Else
        roundingFormat = 0
    End If
    
    previewNum = CDbl(previewTextBox.Value)
    
    previewNum = WorksheetFunction.Round(previewNum, roundingFormat)
    
    resultTextBox.Value = previewNum
    
End Sub

Private Sub UserForm_Initialize()
    roundingTextBox.Value = GetSetting("MagnimetricsTools", "ApplyRounding", "roundingFormat")
End Sub


